Buffon의 바늘 떨어뜨리기

1. 서론

Buffon의 바늘 떨어뜨리기 문제는 기하학적 확률 문제 중에서 매우 전통적인 문제 중의 하나이다. 이 문제는 1977 년에 처음으로 시작되었다. 이 문제는 평행선 들이 일정한 간격으로 그려 있는 종이 위에 바늘들을 떨어뜨릴 때 바늘이 그 평행선의 하나와 만나는 확률을 구하는 문제이다. 그런데 이 확률은 직접원주율과 관계가 있다는 데 이 문제의 중요성이 있다고 하겠다. 여기서는 바늘의 길이가 이웃하는 두 평행선 사이의 거리와 일치할 때 떨어뜨린 바늘이 평행선 중 하나와 만날 확률을 정확히 구하는 방법을 설명하고, 이 확률을 전산시늉(simulation)으로 구하는 프로그램을 전산시늉의 방법과 visualization을 결합하는 한 예제로 보이도록 하겠다.

2. 이론

먼저 가장 간단한 경우를 생각해 보자. 이 경우에서는 바늘의 길이도 1로 이웃하는 평행선 사이의 간격도 1로 두기로 하자. 그러면 이 경우를 분석하기 위하여 두 변수를 도입하여야 한다. 하나는 바늘이 평행선과 이루는 각 q와 바늘의 중심과 가장 가까운 평행선 사이의 거리 D 이다. q는 0부터 p까지 변하며, 바늘의 중심에서 평행선들에 평행한 직선을 그려 그 직선과 바늘이 만드는 각을 측정하여 정하면 된다. 거리 D 는 이웃하는 두 평행선 사이의 거리의 반보다는 클 수 없다. 즉 D < 1/2(D = 1/2인 경우도 포함)이 성립한다. 아래의 그림이 바로 이 경우의 일반적인 경우를 설명해 주고 있다.

이 그림에서 바늘은 평행선과 교차하지 않고 있다. 그림에서 보듯이 바늘은 D 가 D <= (1/2)sin(q)를 만족할 때에만 평행선과 교차하게 된다. 이런 교차가 일어날 확률 P은 어떻게 될까? 아래 그림에서와 같이 D 를 세로축 q를 가로축으로 나타내면, 바늘을 무작위로 종이 위에 바늘의 (D,q)는 0< D <1 과 0 < q < p 의 두 부등호를 동시에 만족하는 직사각형 안에 있다. 이 때 바늘이 평행선과 교차하려면 D <= (1/2)sin(q)를 만족해야 하므로 교차할 확률은 그림에서 칠해진 부분의 면적에 비례한다.

그림에서 칠해진 부분의 면적은 함수 f(q)=(1/2)sin(q)를 0 부터 p 까지 적분한 값과 같으므로 1 과 같다. 따라서 우리가 구하는 확률 P는

P=1/( p/2)= 2/ p

또는

p = 2/P

를 만족한다. P값은 약 .6366197로 알려져 있다. 따라서 만약 바늘을 무수히 많이 떨어뜨려 p 값을 구한다면 P는

P = (교차한 바늘의수)/(총 떨어뜨린 바늘 수)

를 나타내므로

p =[ 2 X (총 떨어뜨린 바늘 수 ) ] / (교차한 바늘의수) (AAA)

참고로 다른 두 경우에 대해 언급하면 다음과 같다. 바늘의 길이를 L, 이웃하는 평행선 사이의 거리를 K 라 하면 L<K인 경우에는

P= 2L/(K p)

를 만족한다. 그러나 L>K인 경우에는 좀 더 복잡한 결과가 나온다고 알려져 있다.

3. 전산 시늉

이제 이러한 바늘 떨어뜨리기를 이용하여 p의 수치 값을 구하는 전산 시늉(Computer Simulation)을 위한 VB프로 그램을 작성해 보자. 이 프로 그램을 실행해 보면 실제로 실험을 하지 않고 computer로 실험 할 수 있는 가를 알 수 있을 것이다. 실제로 바를 떨어뜨리기를 실험해 보려면 바늘과 평행선을 그은 종이 등 다양하게 준비하여야 하지만 전산 시늉(또는 전산 실험:computer experiment)은 그러한 불편 없이 실험을 재현하므로 얼마나 비용, 시간 및 인간의 노력을 절약할 수 있는 가를 알 수 있다.

전산 시늉에서는 실제로 평행선 들을 무수히 많이 그을 필요가 없다. 단 두 개의 평행선이면 충분하다. 왜냐하면 평행선 사이의 거리가 바늘의 길이와 같을 때는 실제로 가장 가까운 평행선 두 개만 확률을 정하는 데 필요하기 때문이다. 또 이 실험에서 중요한 것은 바늘의 중심에서 가장 가까운 평행선까지의 거리 D 이므로 바늘의 중심을 평행선과 평행한 방향으로 평행이동 해도 문제가 생기지 않는다. 따라서 모든 바늘의 중심의 위치 중 평행선에 평행한 방향의 위치는 전산 실험에서 평행선분의 중심에만 있다고 가정하여도 무방하다. 다음 그림이 바로 바늘 떨어뜨리기를 76 번 했을 때 떨어진 바늘 (빨간색 선분들)과 그 때 (AAA) 식으로 p(Pi) 를 예측한 값을 나타내고 있다. 그림에서 검정색 배경의 도표는 바늘이 하나 떨어질 때 마다 p(Pi) 값을 계산하여 도표로 나타낸 그림이다.

이제 이러한 프로그램을 구체적으로 설명해 보자. 이 프로그램의 form file, project file은 실행 file은 각각 needle.frm, needle.vbp, needle.exe이다. 먼저 위의 그림과 같은 form을 구성하는 여러 control들의 속성 표를 작성해 보자.

객체(control)	속성	설정
폼	Name Caption BackColor	FrmNeedle The Needle Program White
Label(결과를 나타내기 위한 레이블: ”던진 횟수” 등이있는 곳)	Name BackColor Caption	lblResult Gray 없음
Line (종이 위의 평행선 첫번째 것)	Name BorderColor BorderWidth	par1Line Black 5
Line (종이 위의 평행선 첫번째 것)	Name BorderColor BorderWidth	par2Line Black 5
Picture Box(p의 수치 값을 그래프로 나타내기 위한 검정색 바탕의 Box)	Name BackColor BorderStyle	picResult Black 1-Fixed Single
Line(Picture Box 안의 x 축)	Name BorderWidth	cxLine 1
Line(Picture Box 안의 y축)	Name BorderWidth	cyLine 1
Line(Picture Box 안의 3.14 값을 나타내는 녹색 줄)	Name BorderStyle BoderColor	piLine 5-Dash-Dot-Dot Green
Line(Picture Box 안의 6.28값을 나타내는 녹색 줄)	Name BorderStyle BoderColor	Pi2Line 5-Dash-Dot-Dot Green
TextBox(Picture Box 안의 “3.14”을 표시하는 TextBox )	Name Text	txtPi 3.14
TextBox(Picture Box 안의 “6.28”을 표시하는 TextBox )	Name Text	txtPi2 6.28
Command	Name Caption	cmdExit Exit
Command	Name Caption	cmdHdrs 100 DRS.
Command	Name Caption	cmdOneDrop 1 Drop

다음으로 실제로 program source code를 살펴보자.

먼저 일반 선언부를 살펴보자.

Option Explicit

Dim gTotal As Long

gTotal은 전역변수로 바늘을 떨어뜨린 총 수를 나타낸다.

Dim gCross As Long

gCross은 전역변수로 평행선과 교차한 바늘의 수를 나타낸다

Dim Pi As Double

Pi도 전역변수로 (AAA) 식으로부터 얻은 p의 수치 값을 나타낸다.

다음으로 Exit Button을 Click 하면 프로그램을 끝내는 프로그램 code 는 다음과 같다.

Private Sub cmdExit_Click()

End

End Sub

다음 code는 프로그램이 시행되면(Form_Load() 시) 곧 바로 시행되는 명령들로 각 변수 값을 0으로 초기화하는 명령들이다.

Private Sub Form_Load()

gTotal = 0

gCross = 0

Pi = 0

End Sub

다음 module이 바로 1 Drop Button을 Click 하면 수행되는 명령들로 바늘이 한 개씩 순차적으로 떨어지고 그 때마다 바늘이 평행선과 교차하는지 여부를 판단하여 떨어진 바늘의 수를 누적하고, 교차한 바늘의 수를 누적하여 (AAA) 식에 의해 Pi의 수치 값을 계산하여 lblLabel에 그 결과를 text로 표시하고, Picture Box에 그 결과를 Graph로 표시하는 프로그램이다.

Private Sub cmdOneDrop_Click()

먼저 변수 필요한 변수들을 선언한다.

Dim CX, CY, RX, RY, LX, LY As Long

Dim Th As Double

Dim DX, DY As Double

Dim Info As String

먼저 한 바늘이 떨어질 때 그 바늘의 중심 위치를 정한다. 바늘의 중심의 X 좌표(CX)는 항상 두 평행 선분의 중앙의 X 좌표와 일치시킨다.

즉 평행선분의 길이 (par1Line.X2 - par1Line.X1)를 반으로 나누어 위에 위치한 평행선분의 한 쪽 위치의 X좌표(par1Line.X1 )를 더하면 CX를 구할 수 있다.

CX = 0.5 * (par1Line.X2 - par1Line.X1) + par1Line.X1

또 바늘의 중심의 Y 좌표(CY)는 평행선분 사이 어느점에도 임의로 떨어질 수 있다. 이 말은 VB가 주는 난수 Rnd(0과 1 사이의 random number)를 이용하여 두 평행 선분 사이의 거리 (par2Line.Y1 - par1Line.Y1)를 임의로 나누는 작업의 하고 (par2Line.Y1 - par1Line.Y1)*Rnd로 하고 이를 Int( )로 정수화 한 다음 위에 위치한 평행선분의 Y 좌표 par1Line.Y1 더해주면 임의의 위치에 떨어진 바늘의 중심 위치를 전산 시늉할 수 있다.

CY = Int(Rnd * (par2Line.Y1 - par1Line.Y1)) + par1Line.Y1

다음으로 떨어진 바늘의 방향과 평행선이 이루는 각(Th)을 모사하기 위해 0과 p사이의 임의의 값을 무작위로 구하는 프로그램이다.

Th = Rnd * 3.141592

다음은 바늘의 중심에서 바늘의 양끝의 위치를 가늠하는 X좌표와 Y 좌표의 절대 값을 DX와 DY로 계산하는 명령이다. 여기서 유의할 점은 바늘의 길이가 두 평행선분의 사이의 길이(par2Line.Y1 - par1Line.Y1) 와 일치한다는 사실이다.

DX = 0.5 * (par2Line.Y1 - par1Line.Y1) * Cos(Th)

DY = 0.5 * (par2Line.Y1 - par1Line.Y1) * Sin(Th)

이 값들과 바늘의 중심의 좌표로부터 바늘의 양쪽 끝의 위치 (RX,RY), (LX,LY)를 계산한다.

RX = CX + DX

RY = CY + DY

LX = CX - DX

LY = CY - DY

이들로부터 떨어진 바늘을 빨간색의 선분으로 표시한다.

frmNeedle.Line (RX, RY)-(LX, LY), RGB(255, 0, 0)

이제 떨어뜨린 바늘의 총수를 하나 증가시키고

gTotal = gTotal + 1

바늘의 양쪽 끝의 Y 좌표 중 하나가 두 평행 선분의 Y 좌표와 비교하여 바늘이 평행선과 교차하는지 여부를 보아서

If RY > par2Line.Y1 Or LY < par1Line.Y1 Then

교차하면 교차한 횟수 하나 올린다.

gCross = gCross + 1

End If

이제 Pi 값을 계산해 보자.

If gCross = 0 Then

만약 교차한 누적 횟수가 0 이면 추정하는 Pi 값이 0이다.

Pi = 0

만약 교차한 누적 횟수가 0 이 아니면

Else

Pi = 2 * gTotal / gCross

로 추정하는 Pi 값을 계산할 수 있다.

End If

결과를 다음과 같이 표시한다. 먼저 picture box안에 계산한 Pi 값에 맞는 조그만 원(흰색깔) 원을 그린다. 원의 중심의 X 좌표는 떨어뜨린 바늘의 수에 비례하여 X 을 따라 움직이게 하고 즉 gTotal * 10 + cyLin.X1을 X 좌표로 한다. 또 3.14와 6.28을 나타내는 두 직선의 Y 좌표의 차이 piLin.Y1 - pi2Lin.Y1를 3.141592로 두어 (piLin.Y1 - pi2Lin.Y1) * Pi / 3.141592로 구한 Pi 값을 표시하되 X 축의 Y값 cxLin.Y2에서 이 값을 빼서 원의 중심의 Y 값으로 하여 원을 그리면 된다.

picResult.Circle (gTotal * 10 + cyLin.X1, cxLin.Y2 - Int((piLin.Y1 - pi2Lin.Y1) * Pi / 3.141592)), 5, RGB(255, 255, 255)

다음으로 lblResult에 계산한 결과를 나타낸다. 먼저 “던진횟수=” 에 던진 총수를 문자로 나타내는 Str(gTotal)을 쓰고 다음으로 줄 바꾸고(Chr(13)) , 바꾼 줄의 제일 앞으로 가고(Chr(10)) 간 다음, "만난 횟수 = " 에 만난 총수를 문자로 나타내는 Str(gTotal)을 쓰고 다음으로 줄바꾸고(Chr(13)) , 바꾼 줄의 제일 앞으로 가고(Chr(10)) 가서, "Pi= " 에 계산한 Pi 값을 문자로 나타내는 Str(Pi)을 쓰고 이 결과를 lblResult의 Caption에 보내면 된다.

Info = "던진 횟수 = " + Str(gTotal) + Chr(13) + Chr(10)

Info = Info + "만난 횟수 = " + Str(gCross) + Chr(13) + Chr(10)

Info = Info + "Pi= " + Str(Pi)

lblResult.Caption = Info

End Sub

다음은 바늘을 한꺼번에 100개씩 떨어뜨리는 프로그램으로 100 DRS. Button을 Click하면 된다. 이 프로그램은 바늘이 100개 떨어질 때의 모양만 나타내고 이 결과로부터 Pi 값을 계산하는 과정은 없다.

Private Sub cmdHrds_Click()

Dim Count As Single

Dim CX, CY, RX, RY, LX, LY As Long

Dim Th As Double

Dim DX, DY As Double

CX = 0.5 * (par1Line.X2 - par1Line.X1) + par1Line.X1 'Int(Rnd * (par1Line.X2 - par1Line.X1)) + par1Line.X1

Count = 1

Do While Count < 1001

CY = Int(Rnd * (par2Line.Y1 - par1Line.Y1)) + par1Line.Y1

Th = Rnd * 2 * 3.141592

DX = 0.5 * (par2Line.Y1 - par1Line.Y1) * Cos(Th)

DY = 0.5 * (par2Line.Y1 - par1Line.Y1) * Sin(Th)

RX = CX + DX

RY = CY + DY

LX = CX - DX

LY = CY - DY

frmNeedle.Line (RX, RY)-(LX, LY), RGB(0, 255, 0)

Count = Count + 1

Loop

frmNeedle.Cls

End Sub

연습문제: 바늘100 개를 한꺼번에 떨어뜨렸을 때의 Pi 값을 계산하여 그 결과를 표시하는 프로그램 과정을 procedure
Private Sub cmdHrds_Click()에 삽입하여 보라.